SubProceso Pausa
	Escribir ""
	Escribir "<enter> para continuar .."
	Escribir ""
	Esperar Tecla
FinSubProceso
SubProceso menu
	Limpiar Pantalla
	Escribir ""
	Escribir "menú"
	Escribir "1. Capturar nombre y edad "
	Escribir "2. Capturar nombre y tres calificaciones"
	Escribir "3. salir"
	Escribir ""
FinSubProceso
SubProceso capturarEdad
	Limpiar Pantalla
	Escribir ""
	Escribir "captura de nombre y edad .."
	Escribir ""
	Escribir "nombre ?"
	Leer vNombre
	Escribir "edad ?"
	Leer vEdad
	Escribir ""
	Si(vEdad>=18)Entonces
		Escribir vNombre," eres MAYOR de edad.."
		Escribir "edad = ",vEdad
	Sino
		Escribir vNombre," eres MENOR de edad.."
		Escribir "edad = ",vEdad
	FinSi
	Pausa
FinSubProceso
SubProceso capturarCalificaciones
	Limpiar Pantalla
	Escribir ""
	Escribir "captura de  calificaciones "
	Escribir ""
	Escribir "nombre ?"
	Leer vNombre
	Escribir vNombre," cuántas calificaciones son ?"
	Leer vCuantas
	vAcum<-0
	Para M<-1 Hasta vCuantas Hacer
		Escribir "calificación no.",M," ?"
		Leer vCalif
		vAcum<-vAcum+vCalif
	FinPara
	vProm<-vAcum/vCuantas
	Escribir ""
	Escribir vNombre," tu promedio es ",vProm
	Si(vProm>=7)Entonces
		Escribir vNombre," estás aprobrado"
	Sino
		Escribir vNombre," estás REPROBADO"
	FinSi
	Pausa
FinSubProceso
Proceso ejemplo
	Repetir
		menu
		Escribir "Qué opción deseas ?.."
		Leer resp
		Segun resp Hacer
			1:capturarEdad
			2:capturarCalificaciones
		FinSegun
	Hasta Que resp=3
FinProceso