SubProceso Pausa
	Escribir ""
	Escribir "<enter> para continuar..."
	Esperar Tecla
FinSubProceso
SubProceso menu
	Limpiar Pantalla
	Escribir "menú"
	Escribir "1. Leer números"
	Escribir "2. Leer nombres y edades "
	Escribir "3. salir"
	Escribir ""
	Escribir "Qué opción deseas ?"
FinSubProceso
SubProceso LeerNumeros
	Limpiar Pantalla
	Escribir "Lectura de números "
	Escribir "cuántos números quieres leer ?"
	Leer vCantidad
	vMayor<-0
	vMenor<-10000
	Para M<-1 Hasta vCantidad Con Paso 1
		Escribir "valor no.",M," ?"
		Leer vValor
		Si(vValor>vMayor)Entonces 
			vMayor<-vValor
		FinSi
		Si(vValor<vMenor)Entonces
			vMenor<-vValor
		FinSi
	FinPara
	Escribir "El mayor es ",vMayor
	Escribir "El menor es ",vMenor
	Pausa 
FinSubProceso
SubProceso LeerNombres
	Limpiar Pantalla
	Escribir "captura de nombres y edades "
	Escribir "Cuántas Personas son ?"
	Leer cantidad
	vEdadMenor<-1000
	vNombreMenor<-""
	vEdadMayor<-0
	vNombreMayor<-""
	Para M<-1 Hasta cantidad Con Paso 1
		Escribir "Datos de la persona no.",M," ?"
		Escribir "nombre ?"
		Leer vNombre
		Escribir "edad ?"
		Leer vEdad
		Si(vEdad>vEdadMayor)Entonces
			vEdadMayor<-vEdad
			vNombreMayor<-vNombre
		FinSi
		Si(vEdad<vEdadMenor)Entonces
			vEdadMenor<-vEdad
			vNombreMenor<-vNombre
		FinSi
	FinPara
	Escribir "el mayor es ",vNombreMayor
	Escribir "su edad es ",vEdadMayor
	Escribir "el menor es ",vNombreMenor
	Escribir "su edad es ",vEdadMenor
	Pausa
FinSubProceso
Proceso Principal
	op<-0
	Repetir 
		menu
		Leer op
		Segun op Hacer
			1:LeerNumeros
			2:LeerNombres
		FinSegun
	Hasta Que op=3
FinProceso